WIN11使用旧版记事本和txt文本文件关联“记事本”

迅恒数据中心 2026-10-12

新版UWP记事本很难用，我们可以恢复旧版记事本并关联txt文件：

@echo off
color 1f
chcp 936 >nul
title 修复TXT文件关联

:: 自动请求管理员权限
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
echo 请求管理员权限...
goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B

:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%~dp0"

echo 修复TXT文件关联到记事本...

:: ===== .txt 扩展名关联 =====
reg add "HKCR\.txt" /ve /d "txtfile" /f >nul
reg add "HKCR\.txt" /v "Content Type" /t REG_SZ /d "text/plain" /f >nul
reg add "HKCR\.txt" /v "PerceivedType" /t REG_SZ /d "text" /f >nul

:: ===== 右键新建文本文档 =====
reg add "HKCR\.txt\ShellNew" /v "NullFile" /t REG_SZ /d "" /f >nul

:: ===== txtfile 类定义 =====
reg add "HKCR\txtfile" /ve /d "Text Document" /f >nul
reg add "HKCR\txtfile" /v "EditFlags" /t REG_DWORD /d 0x210000 /f >nul
reg add "HKCR\txtfile" /v "FriendlyTypeName" /t REG_EXPAND_SZ /d "@%%SystemRoot%%\system32\notepad.exe,-469" /f >nul

:: ===== 图标 =====
reg add "HKCR\txtfile\DefaultIcon" /ve /t REG_EXPAND_SZ /d "%%SystemRoot%%\system32\imageres.dll,-102" /f >nul

:: ===== 打开方式 =====
reg add "HKCR\txtfile\shell\open\command" /ve /t REG_EXPAND_SZ /d "%%SystemRoot%%\system32\NOTEPAD.EXE %%1" /f >nul

:: ===== 打印 =====
reg add "HKCR\txtfile\shell\print\command" /ve /t REG_EXPAND_SZ /d "%%SystemRoot%%\system32\NOTEPAD.EXE /p %%1" /f >nul

:: ===== 打印到 =====
reg add "HKCR\txtfile\shell\printto\command" /ve /t REG_EXPAND_SZ /d "%%SystemRoot%%\system32\notepad.exe /pt \"%%1\" \"%%2\" \"%%3\" \"%%4\"" /f >nul

:: ===== 删除 notepad.exe 的 NoOpenWith（恢复"打开方式"列表里的记事本） =====
reg delete "HKCR\Applications\notepad.exe" /v "NoOpenWith" /f >nul 2>&1

echo.
echo TXT 文件关联修复完成！
pause

请将以上脚本保存为bat(编码为ANSI格式)执行即可

分类：教程帮助百度收录必应收录

本文地址： http://www.piis.cn/jiaocheng/2885.html

文章来源：网络小编D